５. Delphi+Quadruple Dを用いた3D画像表示機能の実装

interface

uses//TimeGetTimeを使うのでMMSystemを追加する。
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DGCarad9, SXLib9, d3d9, s_mathpack, AppEvnts, Ddidex, MMSystem;

const
  //今回は、同じ筒状のポリゴンモデルを複数使って、さもチューブの中を移動しているように見せる。
  backnumber=10;//今回使う背景ポリゴンモデルの数

type
  TForm1 = class(TForm)
    DG: TDGCarad;
    ApplicationEvents1: TApplicationEvents;
    DDIDEX1: TDDIDEX;

    procedure FormCreate(Sender: TObject);//起動時に呼び出される命令

    //↓CPUが暇になると自動的に呼び出される命令
    procedure ApplicationEvents1Idle(Sender: TObject; var Done: Boolean);

    procedure FormDestroy(Sender: TObject);//form1のイベントで追加すること

  private
    { Private 宣言 }
    Root:TSXFrame;      //全てのフレームの親になるフレーム

    MechFrame:array[0..backnumber-1] of TSXFrame;//背景のフレーム

    Camera:TSXFrame;    //カメラの位置・姿勢を示すフレーム

    Mech:TSXMesh;       //背景の形状データ（背景のフレーム内に描画される）

    Lights:TSXLightGroup; //照明管理オブジェクト

    Scene:TSXScene;       //描画の面倒を見るオブジェクト
    steptime:cardinal;    //60FPSを作り出すために、TimeGetTimeの戻り値を入れる
    tick:integer;         //ゲーム開始後何フレーム時間目か。

    procedure mainloop();//この処理をApplicationEvents1Idle手続きの中で、1秒に約60回やってくれる
    procedure makegraphic();//この処理をApplicationEvents1Idle手続きの中で、1秒に約60回やってくれる

  public
    { Public 宣言 }

  end;
var
  Form1: TForm1;

////////////////////
//
//アプリ起動時に呼ばれる
//
/////////////////////
procedure TForm1.FormCreate(Sender: TObject);
var
  tmpint:integer;//for文の作業用変数
begin
//解像度とデプスステンシルサーフェスの設定　ポリゴンモデルを表示できるようにする。
//スプライト表示のみの時とは第三引数が違うが、このままでちゃんとスプライト表示できる。
  DG.WindowMode(ClientWidth, ClientHeight, DGFMT_ZCheap);

  //シーンオブジェクトの生成　
  Scene:=TSXScene.Create(DG);

  //ビューポートの設定、つまり、三次元空間の見え方の設定。
  Scene.SetProjection(Pi/2, ClientHeight/ClientWidth, 0.01, 10000.0);
  Scene.SetViewport(0,0,ClientWidth,ClientHeight);

    //フレームの作成
  Root:=TSXFrame.Create(Nil);
  Camera:=TSXFrame.Create(Root);
  Scene.CameraFrame:=Camera;

  //カメラの位置・姿勢を決める
  Camera.SetTranslation(Root, Vector(0,0,1));//カメラの位置
  Camera.SetOrientation(Root, Vector(0,0,1), Vector(0,1,0));//カメラの角度

  //背景ポリゴンモデル読み込み
  Mech:=TSXMesh.Create(DG);
  Mech.LoadFromFile('3dback_l3.sx');//ポリゴンモデルをファイルから読み込む

  //ポリゴンモデルにそれぞれテクスチャを貼り付ける
  //スプライトのテクスチャ作成とやり方は一緒。
  for tmpint:=0 to backnumber-1 do
    begin
      MechFrame[tmpint]:=TSXFrame.Create(Root);//親フレームはRoot
      MechFrame[tmpint].Mesh:=Mech;//内容はMech
      //2Dスプライトの時と同様、テクスチャを設定する
      mechframe[tmpint].Texture:=TDGTexture.Create(DG, DGFMT_ARGB); //できればαチャンネル付きで
      mechframe[tmpint].Texture.BorderColor:=$00000000;
      MechFrame[tmpint].Texture.LoadFromFile('mecha1.bmp');//テクスチャをファイルから読み込む
    end;

    //ライトの設定
    //今回は二方向から光を当てる。
  Lights:=TSXLightGroup.Create(DG, 2);
  //光の色、強さ
  Lights[0].SetupDiffuse(8,8,8);
  Lights[0].SetupSpecular(4,4,4);
  Lights[0].SetupAmbient(2,2,2);
  //光の向き
  Lights[0].SetupDirectional(Vector(0.3,0.3,1));
  //Trueにしないと有効にならない。デフォルトはOFFなので。
  Lights[0].Enabled:=True;

  Lights[1].SetupDiffuse(6,6,6);
  Lights[1].SetupSpecular(4,4,4);
  Lights[1].SetupAmbient(1,1,1);

  Lights[1].SetupDirectional(Vector(-0.2,-0.2,1));
  Lights[1].Enabled:=true;
  //Tick:ゲームがはじまってから何フレーム時間目か。
  Tick:=0;
  TimeBeginPeriod(1);//TimeGetTimeの精度を上げる
end;

////////////////////
//
//アプリケーションが終了時呼び出される
//
/////////////////////
procedure TForm1.FormDestroy(Sender: TObject);//Form1のOnDestroyイベント
var
  tmpint:integer;//for文の作業用
begin
  TimeEndPeriod(1);//TimeBeginPeriod(1)とセットで記述する。
//それぞれ解放
  camera.Free;

  for tmpint:=0 to backnumber-1 do
    begin
      MechFrame[tmpint].Free;
    end;
   mech.Free;
  Lights.Free;
  root.Free;
  scene.free;
end;

////////////////////
//
//CPUが暇になったら真っ先に呼ばれる。
//
/////////////////////
procedure TForm1.ApplicationEvents1Idle(Sender: TObject; var Done: Boolean);
var
  m:integer;//mは次のTGTまでの時間をいれとく
begin
  //TimeGetTimeはWindowsが起動してからの時間をミリ秒で返す関数
            if TimeGetTime>=steptime+17 then//1000/60=16.7だいたい17ということで
            begin
            //メインループ
            mainloop();

            steptime:=steptime+17;//次タイミングを決定

            m:=steptime-TimeGetTime;
            if m>3 then  //残り3msまでは一気にとばす。

              begin
//下二行の処理は、この間に他のアプリにCPU時間を分ける。じゃないと、OSがとても重くなる。
                Sleep(m-3);//このアプリは(m-3)ms処理を休む
              end;
        end else
            begin
              Sleep(0);//ここらへんの処理は結構いろんな意見がある。
            end;

  //これを設定すると、他のイベントが実行されなくてもまたこのイベントが呼ばれる
  Done:=False;
end;

////////////////////
//
//メインループの中身。1秒に60回呼ばれる。つまり１フレーム時間分の処理。
//
/////////////////////
procedure TForm1.mainloop;
var
  tmpHRESULT:HRESULT;//DG.D3DDevice.TestcooperativeLevelの返り値を一時的に格納させる
begin
//1フレーム時間に一回、DG.D3DDevice.TestcooperativeLevelでD3D_OK を得なくてはならないので、
//Quadruple Dのサンプルとは違ってこんな風にした。

  tmpHRESULT:=DG.D3DDevice.TestcooperativeLevel;
  while tmpHRESULT<>D3D_OK do
    begin
    //デバイスは生きてるけど、ロスト後でリセットされてない
        // 何故かここで少なくともD3DERR_DEVICENOTRESETをintegerにキャストしないと
        //警告が出る。そもそも次の行の意味があるのかがよくわからないが一応。
                //QD3のサンプルでも警告が出てるし。
      if  integer(tmpHRESULT)=integer(D3DERR_DEVICENOTRESET) then DG.Reset;
      tmpHRESULT:=DG.D3DDevice.TestcooperativeLevel;
    end;
    //ここまでくるってことは、D3D_OKを得たと言うこと。生きてます。
      //描画開始
      DG.D3DDevice.BeginScene;

///////
      makegraphic();//ここで各キャラクター、背景等の画像処理を行う
///////

      //シーンの内容を全部描く
      Scene.Render(Root);

      //描画終わり
      DG.D3DDevice.EndScene;

      //表示
      DG.D3DDevice.Present(Nil, Nil, 0, Nil);
end;

////////////////////
//
//キャラクターおよび背景の配置処理
//
/////////////////////
procedure TForm1.makegraphic;
var
  tmpint:integer;//for文の作業用
begin

//背景のポリゴンモデルをかいていきましょう
    //画面を黒でクリアー。 2Dの時とは、第一引数が違うことに注意。が、このままでも
    //2Dで使える。
    Scene.Clear(D3DCLEAR_TARGET Or D3DCLEAR_ZBUFFER, $00000000, 1.0, 0);

	Application.ProcessMessages;//他のアプリに処理をさせる
                    
    //1フレーム時間ごとにtickを1増やす
    inc(tick);
    //1フレーム時間ごとにカメラを左右に首ふりさせる。
    Camera.SetOrientation(Root, NowRotY( Vector(0,0,1),round(sin(tick/700)*1000)), Vector(0,1,0));
    //１フレーム時間ごとに背景の各ポリゴンモデルの位置と角度を変える。
    for tmpint:=0 to backnumber-1 do
      begin
        //１フレーム時間ごとにポリゴンモデルを手前（Z軸的に負方向）に移動させ、
        //十分手前に来たら、また奥に戻す。
        MechFrame[tmpint].SetTranslation(Root, Vector(0,0,((10-((tick+(300*tmpint div backnumber)) mod 300)/27) ) ));
        //1フレーム時間ごとに、ポリゴンモデルをZ軸を中心に回転させる。見栄え良し。
        MechFrame[tmpint].SetOrientation(Root, Vector(0,0,1), NowRotZ(vector(0,1,0),tick));
      end;
end;