３. 避けゲーを創る on Delphi

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DGCarad9, SXLib9, d3d9, s_mathpack, AppEvnts, Ddidex, MMSystem;

////////////////////
//
//CPUが暇になったら真っ先に呼ばれる。
//
/////////////////////
procedure TForm1.ApplicationEvents1Idle(Sender: TObject;var Done: Boolean);
var
  m:integer;//mは次のTGTまでの時間をいれとく
begin
  //TimeGetTimeはWindowsが起動してからの時間をミリ秒で返す関数
            if TimeGetTime>=steptime+17 then//1000/60=16.7だいたい17ということで
            begin
            //メインループ
            mainloop();

            //次タイミングを決定
            steptime:=steptime+17;

          //次のタイミングまで残り3msまでは一気にとばす。
            m:=steptime-TimeGetTime;
            if m>3 then
              begin
//下の行の処理は、この間に他のアプリにCPU時間を分ける。じゃないと、OSがとても重くなる。
                Sleep(m-3);//このアプリは(m-3)ms処理を休む
              end;
            end
          else
            begin
              Sleep(0);//ここらへんの処理は、結構いろんな意見がある。
            end;
//以上メインループ

//↓これを設定すると、他のイベントが実行されなくてもまたApplicationEvents1Idleが呼ばれる
  Done:=False;
end;

////////////////////
//
//アプリ起動時に呼ばれる
//
/////////////////////
procedure TForm1.FormCreate(Sender: TObject);
begin
  //とりあえずクライアント領域のサイズに合わせて画面を初期化
  DG.WindowMode(ClientWidth, ClientHeight, []);

  //シーンオブジェクトの作成
  Scene:=TSXScene.Create(DG);

  TimeBeginPeriod(1);//TimeGetTimeの精度を上げる
end;

////////////////////
//
//アプリケーションが終了時呼び出される
//
/////////////////////
procedure TForm1.FormDestroy(Sender: TObject);//Form1のOnDestroyイベント
begin
  TimeEndPeriod(1);//TimeBeginPeriod(1)とセットで記述する。
  //Sceneオブジェクトの解放。
  //Scene:=TSXScene.Create(DG);とセットだと思って下さい。
  //createしたものは、あとでfreeする必要があると覚えておいて下さい。    
  Scene.Free;
end;

////////////////////
//
//メインループの中身。1秒に60回呼ばれる。つまり１フレーム分の処理
//
/////////////////////
procedure TForm1.mainloop;
var
//DG.D3DDevice.TestcooperativeLevelの返り値を一時的に格納させる
  tmpHRESULT:HRESULT;
begin
  tmpHRESULT:=DG.D3DDevice.TestcooperativeLevel;
    
  if tmpHRESULT<>D3D_OK then
    begin
    //アプリをフル画面で起動したとき、Alt+Tabとかするとこっちにくる。普通はこっちにきません。
      Application.Terminate;//まあ、システムに何かがあったのは間違いないので、トラブルを避けるために今回は、単純にアプリケーション終了しちゃう。
      exit;
    end;
    
    
    //ここまでくるってことは、D3D_OKを得たと言うこと。生きてます。
      //描画開始
      DG.D3DDevice.BeginScene;


/////////ここでスプライトを置く
      makegraphic();
///////

      //シーンの内容を全部描く
      Scene.Render(Nil);

      //描画終わり
      DG.D3DDevice.EndScene;

      //表示
      DG.D3DDevice.Present(Nil, Nil, 0, Nil);
end;

////////////////////
//
//スプライトを置く作業を簡単にするラッピングメソッド
//
/////////////////////
procedure TForm1.putsprite(ture:TDGtexture; x, y: integer);
//単純にスプライトを置く際に楽をできるようにします。
//毎回、下のような記述をするのはイヤでしょ？
begin

//Quadruplle DのマニュアルDG-Carad第一章の解説参照
      Scene.PushSprite(
        Vector2D(x,y),
        [

          SXVertexSP(0,0, $FFFFFFFF, 0.0,0.0),
          SXVertexSP(ture.Width, 0, $FFFFFFFF, ture.U, 0.0),
          SXVertexSP(0,ture.Height, $FFFFFFFF, 0.0,ture.V),
          SXVertexSP(ture.Width,ture.Height, $FFFFFFFF, ture.U,ture.V)
        ],
        ture,
        sxbAlpha,
        false,
        true//後に描画された物ほど手前に書かれるようにする
      );
end;